|
|
Tandy QuickEnter |
"PocketQuicken for the M100" With Jeffs program, you can use the M100 to enter in data than can be exported in quick .QIF format, for inport into Quicken on your PC.
Here is the text for a BASIC file I wrote... I wanted to be able to enter my checks and other transactions for Quicken on my PC, but didn't want to sit in my office to do it. This program will let you use your Tandy 100/102/200 to create the files of transactions in the QIF format which Quicken can import. It's like "Pocket Quicken" on your Tandy! Save the files to your PC with a QIF extension, and you're all set to import your data into Quicken.
The list of transaction categories is easily customized -- the category lists are clearly marked and near the front of the BASIC file. I really like it -- and it impressed my friends and family! If you try it, let me know what you think. E-mail "jefflabenz@aol.com"
(NOTE: When using Tandy QuickEnter for the first time, choose the option "Create a new QIF file" before you enter transactions. This will save a text file to RAM called CHECKING.DO -- the file you transfer to your PC as a QIF file.)
The text of Tandy QuickEnter follows below:
10 REM QuickEnter for the Tandy 100/102/200 by Jeff La Benz. Written
April 1996.
20 REM NOTES: 1. To create your custom category list, replace the words
between the quotes.
30 REM 2. Don't make any category name longer than 13 characters.
40 REM 3. QuickEnter is set up to allow 22 different categories.
50 REM -----Start:CATEGORY LIST--------
60 CA$="Auto"
70 CB$="Baby Stuff"
80 CC$="Clothing"
90 CD$="Cmptr"
100 CE$="Daycare"
110 CF$="Gas"
120 CG$="Gift"
130 CH$="Groceries"
140 CI$="Restaurant"
150 CJ$="Health"
160 CK$="Mortgage"
170 CM$="Utilities"
180 CN$="Int./Svc Chg"
190 CO$="Salary"
200 CP$="Tax:Charity"
210 CQ$="Tax:Misc Ded"
220 CR$="Tax:Dr/Hosp"
230 CS$="Tax:Rx"
240 CT$="Tax:Refund"
250 CU$="OTHER"
260 CV$="[BofA ODP]"
270 CW$=""
281 REM ** END OF CATEGORY LIST **
290 CL$="More..."
300 CX$="Go Back..."
305 REM
310 REM -----Start:OPENING SCREEN------
320 CLS
330 LINE(0,0)-(91,63),1,BF
340 LINE(1,1)-(90,62),0,B
350 LINE(6,8)-(24,10),0,BF
360 LINE(14,10)-(16,24),0,BF
370 LINE(30,8)-(22,24),0
380 LINE(31,8)-(23,24),0
390 LINE(32,8)-(24,24),0
400 LINE(30,8)-(38,24),0
410 LINE(31,8)-(39,24),0
420 LINE(32,8)-(40,24),0
430 LINE(29,18)-(35,20),0,BF
440 LINE(42,8)-(44,24),0,BF
450 LINE(52,8)-(54,24),0,BF
460 LINE(42,8)-(52,24),0
470 LINE(43,8)-(53,24),0
480 LINE(44,8)-(54,24),0
490 LINE(57,8)-(59,24),0,BF
500 LINE(58,8)-(66,10),0,BF
510 LINE(57,22)-(66,24),0,BF
520 LINE(66,8)-(68,10),0
535 LINE(67,11)-(69,21),0,BF
540 LINE(66,11)-(67,10),0
550 LINE(66,21)-(67,22),0
560 LINE(67,23)-(68,22),0
570 LINE(71,8)-(78,17),0
580 LINE(72,8)-(78,16),0
590 LINE(73,8)-(78,15),0
600 LINE(83,8)-(78,15),0
610 LINE(84,8)-(78,16),0
620 LINE(85,8)-(78,17),0
630 LINE(77,14)-(79,24),0,BF
640 LINE(10,44)-(83,50),0,BF
650 LINE(10,32)-(83,39),0,BF
660 PRINT@162," QuickEnter "
670 LINE(93,0)-(239,63),1,B
680 LINE(95,2)-(237,61),1,B
690 PRINT@58, "A program for making"
700 PRINT@98, " QIF files for easy "
710 PRINT@138," importing into "
720 PRINT@178,"Quicken ( of Intuit)"
730 PRINT@218," By Jeff La Benz "
740 ZA$=INPUT$(1)
750 REM ------End: Opening Screen-------
755 REM ----Start: MAIN MENU-----------
760 OPEN "CHKING" FORAPPENDAS1
800 CLS
810 PRINT@43,"Choose an account activity below:"
820 PRINT@124,"<1> Enter a DEPOSIT or CREDIT"
830 PRINT@164,"<2> Enter a CHECK or DEBIT"
840 PRINT@204,"<3> CREATE a new QIF File
850 PRINT@244,"<4> EXIT Tandy QuickEnter
860 LINE (0,0)-(239,63),1,B
870 W$=INPUT$(1)
880 IFINSTR("1",W$)THEN 1000
890 IFINSTR("2",W$)THEN 2000
900 IFINSTR("3",W$)THEN 3000
910 IFINSTR("4",W$)THEN 4000
920 GOTO800
930 REM ---------End:MAIN MENU----------
1000 REM ---Start:DEPOSIT DATA ENTRY---
1010 CLS
1020 PRINT"Today's date: "DATE$
1030 D$=""
1040 INPUT "Date ";D$
1050 N$="DEP"
1060 P$=""
1070 INPUT "Dep from... ";P$
1080 T$=""
1090 INPUT "Amount ";T$
1100 L$=""
1110 GOSUB5000
1120 T$="T"+T$
1130 GOSUB6000
1140 IFINSTR("rR",U$)THEN GOTO1000
1150 GOSUB7000
1160 PRINT@126,"Enter another Deposit? (Y/N)"
1170 V$=INPUT$(1)
1180 IFINSTR("yY",V$)THEN GOTO1000
1190 GOTO800
1200 REM -----End:DEPOSIT DATA ENTRY----
2000 REM ----Start:CHECK DATA ENTRY----
2005 CLS
2010 PRINT"Today's date: "DATE$
2020 D$=""
2030 INPUT "Date ";D$
2040 N$=""
2050 INPUT "Check Number";N$
2060 P$=""
2070 INPUT "Payee ";P$
2080 T$=""
2090 INPUT "Amount ";T$
2100 L$=""
2110 GOSUB5000
2120 T$="T-"+T$
2130 GOSUB6000
2140 IFINSTR("rR",U$)THEN GOTO2000
2150 GOSUB7000
2160 PRINT@126,"Enter another Check? (Y/N)"
2170 V$=INPUT$(1)
2180 IFINSTR("yY",V$)THEN GOTO2000
2190 GOTO800
2200 REM ------End:CHECK DATA ENTRY-----
3000 REM -----Start:NEW QIF FILE-------
3005 CLS
3010 LINE (0,0)-(239,63),1,B
3020 PRINT@129,"Are you SURE you want to"
3030 PRINT@166,"DELETE your old QIF file? (Y/N)"
3040 B$=INPUT$(1)
3050 IFINSTR("Yy",B$)THEN 3060 ELSEGOTO800
3060 KILL "CHKING.DO"
3070 CLS
3075 LINE (0,0)-(239,63),1,B
3080 PRINT@84, "Old QIF file deleted..."
3090 SOUND 1660,8
3100 SOUND 6642,10
3110 OPEN"CHKING.DO"FOROUTPUTAS1
3120 X$="!Type:Bank"
3130 PRINT#1,USING"\ \";X$
3140 GOTO800
3150 REM -------End:NEW QIF FILE--------
4000 MENU
4010 REM
5000 REM --Start SUB:CHOOSE CATEGORY---
5005 CLS
5010 PRINT@13,"CATEGORIES:"
5020 PRINT@41,"<A> "CA$
5030 PRINT@81,"<B> "CB$
5040 PRINT@121,"<C> "CC$
5050 PRINT@161,"<D> "CD$
5060 PRINT@201,"<E> "CE$
5070 PRINT@241,"<F> "CF$
5080 PRINT@61,"<G> "CG$
5090 PRINT@101,"<H> "CH$
5100 PRINT@141,"<I> "CI$
5110 PRINT@181,"<J> "CJ$
5120 PRINT@221,"<K> "CK$
5130 PRINT@261,"<L> "CL$
5140 ZZ$=INPUT$(1)
5150 IFINSTR("Aa",ZZ$)THEN L$=CA$
5160 IFINSTR("Bb",ZZ$)THEN L$=CB$
5170 IFINSTR("Cc",ZZ$)THEN L$=CC$
5180 IFINSTR("Dd",ZZ$)THEN L$=CD$
5190 IFINSTR("Ee",ZZ$)THEN L$=CE$
5200 IFINSTR("Ff",ZZ$)THEN L$=CF$
5210 IFINSTR("Gg",ZZ$)THEN L$=CG$
5220 IFINSTR("Hh",ZZ$)THEN L$=CH$
5230 IFINSTR("Ii",ZZ$)THEN L$=CI$
5240 IFINSTR("Jj",ZZ$)THEN L$=CJ$
5250 IFINSTR("Kk",ZZ$)THEN L$=CK$
5260 IFINSTR("Ll",ZZ$)THEN GOTO5290
5270 IFINSTR("MmNnOoPpQqRrSsTtUuVvWw",ZZ$) THENGOTO5440
5280 GOTO5570
5290 CLS
5300 PRINT@13,"CATEGORIES:"
5310 PRINT@41,"<M> "CM$
5320 PRINT@81,"<N> "CN$
5330 PRINT@121,"<O> "CO$
5340 PRINT@161,"<P> "CP$
5350 PRINT@201,"<Q> "CQ$
5360 PRINT@241,"<R> "CR$
5370 PRINT@61,"<S> "CS$
5380 PRINT@101,"<T> "CT$
5390 PRINT@141,"<U> "CU$
5400 PRINT@181,"<V> "CV$
5410 PRINT@221,"<W> "CW$
5420 PRINT@261,"<X> "CX$
5430 ZZ$=INPUT$(1)
5440 IFINSTR("Mm",ZZ$)THEN L$=CM$
5450 IFINSTR("Nn",ZZ$)THEN L$=CN$
5460 IFINSTR("Oo",ZZ$)THEN L$=CO$
5470 IFINSTR("Pp",ZZ$)THEN L$=CP$
5480 IFINSTR("Qq",ZZ$)THEN L$=CQ$
5490 IFINSTR("Rr",ZZ$)THEN L$=CR$
5500 IFINSTR("Ss",ZZ$)THEN L$=CS$
5510 IFINSTR("Tt",ZZ$)THEN L$=CT$
5520 IFINSTR("Uu",ZZ$)THEN L$=CU$
5530 IFINSTR("Vv",ZZ$)THEN L$=CV$
5540 IFINSTR("Ww",ZZ$)THEN L$=CW$
5550 IFINSTR("Xx",ZZ$)THEN GOTO5000
5560 IFINSTR("AaBbCcDdEeFfGgHhIiJjKk",ZZ$)THEN GOTO5150
5570 CLS
5580 PRINT@1,"Date: "D$
5590 PRINT@41,"Number: "N$
5600 PRINT@81,"Payee: "P$
5610 PRINT@121,"Amount: $ "T$
5620 PRINT@161,"Category: "L$
5630 RETURN
5640 REM----End SUB:CHOOSE CATEGORY-----
6000 REM ---Start SUB:TRANSACTION OK?--
6010 D$="D"+D$
6020 N$="N"+N$
6030 P$="P"+P$
6040 L$="L"+L$
6050 M$=""
6060 INPUT " Memo ";M$
6070 M$="M"+M$
6080 Z$="^"
6090 PRINT@70,"PRESS:"
6100 PRINT@105," <R> to Redo"
6110 PRINT@145," <C> to Cancel"
6120 PRINT@191,"or"
6130 PRINT@226,"Any other key"
6140 PRINT@266," to go on..."
6150 LINE (151,0)-(239,63),1,B
6160 U$=INPUT$(1)
6170 RETURN
6180 REM ----End SUB:TRANSACTION OK?----
7000 REM ----Start SUB:APPEND DATA-----
7010 IFINSTR("cC",U$)THEN GOTO800
7020 PRINT#1,USING "\ \";D$
7030 PRINT#1,USING"\ \";T$
7040 PRINT#1,USING"\ \";N$
7050 PRINT#1,USING"\ \";P$
7060 PRINT#1,USING"\ \";L$
7070 PRINT#1,USING"\ \";M$
7080 PRINT#1,USING"\ \";Z$
7090 SOUND 6642,10
7100 SOUND 1660,8
7110 CLS
7120 LINE (0,0)-(239,63),1,B
7130 RETURN